- add build option for disabling SELinux support (on rpm >= 4.3)
[apt.git] / configure.ac
1 dnl Process this file with autoconf to produce a configure script.
2
3 AC_PREREQ(2.59)
4 AC_INIT([apt],[0.5.15lorg4],[apt-rpm@lists.laiskiainen.org])
5 dnl Check the archs, we want the target type.
6 AC_CONFIG_AUX_DIR([buildlib])
7 AC_CANONICAL_HOST
8 AC_CONFIG_SRCDIR([AUTHORS.RPM])
9 AM_INIT_AUTOMAKE([foreign subdir-objects dist-bzip2 1.9.5])
10 AM_MAINTAINER_MODE
11
12 AC_CONFIG_HEADER([include/config.h:buildlib/config.h.in])
13
14 AC_PROG_LIBTOOL
15
16 dnl Check our C compiler
17 AC_PROG_CC
18 AM_PROG_CC_C_O
19 AC_ISC_POSIX
20
21 dnl Check for other programs
22 AC_PROG_CXX
23 AC_PROG_CPP
24
25 dnl Checks for sockets
26 SAVE_LIBS="$LIBS"
27 LIBS=""
28 AC_SEARCH_LIBS(gethostbyname,nsl)
29 AC_SEARCH_LIBS(connect,socket)
30 SOCKETLIBS="$LIBS"
31 AC_SUBST(SOCKETLIBS)
32 LIBS="$SAVE_LIBS"
33  
34 dnl Checks for pthread -- disabled due to glibc bugs jgg
35 dnl AC_CHECK_LIB(pthread, pthread_create,[AC_DEFINE(HAVE_PTHREAD) PTHREADLIB="-lpthread"])
36 AC_SUBST(PTHREADLIB)
37 dnl if test "$PTHREADLIB" != "-lpthread"; then
38 dnl   AC_MSG_ERROR(failed: I need posix threads, pthread)
39 dnl fi
40
41 dnl Check for RPM executable path
42 AC_PATH_PROG(RPM_PATH,rpm,none)
43 if test "$RPM_PATH" = "none"; then
44    AC_MSG_ERROR([RPM executable was not found in your system])
45 else
46    AC_DEFINE_UNQUOTED([HAVE_RPM],1,[Define if RPM backend is available])
47
48    dnl Check for RPM version
49    AC_MSG_CHECKING(for RPM version)
50    RPM_VERSION_RAW=`LANG= LC_ALL= $RPM_PATH --version | sed 's/^RPM version //'`
51    RPM_VERSION_MAJOR=`echo $RPM_VERSION_RAW | cut -d. -f1`
52    RPM_VERSION_MINOR=`echo $RPM_VERSION_RAW | cut -d. -f2`
53    RPM_VERSION_MICRO=`echo $RPM_VERSION_RAW | cut -d. -f3`
54    if test -z "$RPM_VERSION_MAJOR" -o -z "$RPM_VERSION_MINOR"; then
55       AC_MSG_ERROR([can't parse RPM version])
56    fi
57    if test -z "$RPM_VERSION_MICRO"; then
58       RPM_VERSION_MICRO=0
59    fi
60    AC_DEFINE_UNQUOTED([RPM_VERSION_MAJOR],$RPM_VERSION_MAJOR,[RPM major version])
61    AC_DEFINE_UNQUOTED([RPM_VERSION_MINOR],$RPM_VERSION_MINOR,[RPM minor version])
62    AC_DEFINE_UNQUOTED([RPM_VERSION_MICRO],$RPM_VERSION_MICRO,[RPM micro version])
63    AC_DEFINE_UNQUOTED([RPM_VERSION],
64       [((RPM_VERSION_MAJOR<<16)|(RPM_VERSION_MINOR<<8)|RPM_VERSION_MICRO)],
65       [Define to the RPM version])
66    AC_DEFINE_UNQUOTED([RPM_VERSION_RAW],"$RPM_VERSION_RAW",[RPM raw version])
67    AC_MSG_RESULT($RPM_VERSION_RAW)
68
69    dnl Check for RPM libraries and headers
70
71    AC_CHECK_LIB(bz2,BZ2_bzopen, [],
72                 [AC_MSG_ERROR([Can't find libbz2 library])])
73    AC_CHECK_LIB(z,gzopen, [],
74                 [AC_MSG_ERROR([Can't find libz library])])
75    AC_CHECK_HEADERS(db1/db.h)
76
77    CPPFLAGS="$CPPFLAGS -I/usr/include/rpm"
78    AC_CHECK_HEADER(rpm/rpmlib.h, [],
79                    [AC_MSG_ERROR([Can't find rpmlib.h])])
80
81    if test $RPM_VERSION_MAJOR -lt 4; then
82       RPMLIBS="-lrpm -lz -lbz2 -lpopt"
83    else
84       AC_CHECK_LIB(rpmdb,rpmdbOpen,
85          [RPMDBLIBS="-lrpmdb"],
86          [RPMDBLIBS="-ldb-3.1"],
87          [-lrpm -lrpmio -lz -lbz2 -lpopt])
88       RPMLIBS="-lrpm $RPMDBLIBS -lrpmio -lz -lbz2 -lpopt"
89    fi
90    AC_MSG_CHECKING(for RPM libraries)
91    AC_MSG_RESULT($RPMLIBS)
92    AC_SUBST(RPMLIBS)
93 fi
94
95 dnl repomd support needs libxml2, not sure about the minimal version - I've
96 dnl only tested it with 2.6.20
97 ## xmlReadFile is not available before 2.6.0
98 PKG_CHECK_MODULES([LIBXML2],[libxml-2.0 >= 2.6])
99 RPMLIBS="$LIBXML2_LIBS $RPMLIBS"
100 CPPFLAGS="$LIBXML2_CFLAGS $CPPFLAGS"
101
102 dnl Can we use g++ hash_map?
103 AH_TEMPLATE(WITH_GNU_HASH_MAP,
104             [Define to 1 if you want to use the g++ hash_map extension])
105 AC_MSG_CHECKING(for g++ hash_map extension)
106 AC_LANG_PUSH([C++])
107 AC_TRY_LINK(
108 [
109 #include <ext/hash_map>
110 using namespace __gnu_cxx;
111 ],[hash_map<char*,hash<char*> > HashMap;
112 ],[AC_DEFINE_UNQUOTED(WITH_GNU_HASH_MAP, 1) AC_MSG_RESULT(yes)
113 ],[AC_MSG_RESULT(no)])
114 AC_LANG_POP([C++])
115
116 dnl CNC:2003-03-20
117 AC_MSG_CHECKING(for --disable-scripts)
118 AC_ARG_ENABLE([scripts],
119               AS_HELP_STRING([--disable-scripts],[disable the lua script extension system]),
120               [enable_scripts="$enableval"],[enable_scripts="yes"])
121 if test "$enable_scripts" != "no"; then
122   AC_MSG_RESULT(no)
123   AC_DEFINE(WITH_LUA, 1, 
124             [Define if you want to enable the extension system]) 
125 else
126   AC_MSG_RESULT(yes)
127 fi
128 AM_CONDITIONAL(WITH_LUA, test "$enable_scripts" != "no")
129
130 dnl SELinux support
131 AC_MSG_CHECKING(for --disable-selinux)
132 AC_ARG_ENABLE([selinux],
133               AS_HELP_STRING([--disable-selinux],
134                              [disable SELinux support]),
135               [enable_selinux="$enableval"],[enable_selinux="yes"])
136 if test "$enable_selinux" != "no"; then
137   AC_MSG_RESULT(no)
138   AC_DEFINE(WITH_SELINUX, 1, 
139             [Define if you want to enable SELinux support]) 
140 else
141   AC_MSG_RESULT(yes)
142 fi
143 AM_CONDITIONAL(WITH_SELINUX, test "$enable_selinux" != "no")
144
145 dnl Before configuring libtool check for --enable-static-progs option
146 AC_MSG_CHECKING(for --enable-static-progs)
147 AC_ARG_ENABLE(static-progs,
148               AS_HELP_STRING([--enable-static-progs],
149                              [build completely static (standalone) binaries]),
150               [enable_static_progs="$enableval"],[enable_static_progs="no"])
151 AM_CONDITIONAL(COMPILE_STATIC, test "$enable_static_progs" = "yes")
152 if test "$enable_static_progs" = "yes" ; then
153   AC_MSG_RESULT(yes)
154 else
155   AC_MSG_RESULT(no)
156 fi
157
158 dnl Check for apt-shell dependencies
159 AC_CHECK_LIB(ncurses,tputs,
160   [AC_CHECK_HEADER(readline/readline.h,
161      [AC_CHECK_LIB(readline,rl_completion_matches,
162         [compile_aptshell=yes],,[-lncurses])])])
163 AM_CONDITIONAL(COMPILE_APTSHELL, test "$compile_aptshell" = "yes")
164
165 dnl Converts the ARCH to be something singular for this general CPU family
166 dnl This is often the dpkg architecture string.
167 AH_TEMPLATE(COMMON_CPU, [Define the common CPU])
168 AH_TEMPLATE(COMMON_OS, [Define the common OS])
169 AC_MSG_CHECKING(system architecture)
170 archset="`awk \" ! /^#|^\\\$/ { if(match(\\\"$host_cpu\\\",\\\"^\\\"\\\$1\\\"\\\$\\\")) {print \\\$2; exit}}\" $srcdir/buildlib/archtable`"
171 if test "x$archset" = "x"; then
172   AC_MSG_ERROR(failed: use --host=)
173 fi
174 AC_MSG_RESULT($archset)
175 AC_DEFINE_UNQUOTED(COMMON_CPU,"$archset")
176
177 dnl Get a common name for the host OS - this is primarily only for HURD and is
178 dnl non fatal if it fails
179 AC_MSG_CHECKING(system OS)
180 osset="`awk \" ! /^#|^\\\$/ {if (match(\\\"$host_vendor-$host_os\\\",\\\$1)) {print \\\$2; exit}}\" $srcdir/buildlib/ostable`"
181 AC_MSG_RESULT($osset)
182 AC_DEFINE_UNQUOTED(COMMON_OS,"$osset")
183
184 dnl We use C99 types if at all possible
185 AC_CACHE_CHECK([for C99 integer types],c9x_ints,[
186     AC_TRY_COMPILE([#include <inttypes.h>],
187                    [uint8_t Foo1;uint16_t Foo2;uint32_t Foo3;],
188                    c9x_ints=yes,c9x_ints=no)])
189
190 AC_C_BIGENDIAN
191
192 dnl Check the sizes etc. of the architecture
193 dnl Cross compilers can either get a real C library or preload the cache
194 dnl with their size values.
195 AC_CHECK_SIZEOF(char)
196 AC_CHECK_SIZEOF(int)
197 AC_CHECK_SIZEOF(short)
198 AC_CHECK_SIZEOF(long)
199
200 dnl Single Unix Spec statvfs
201 AC_CHECK_FUNC(statvfs,[have_statvfs=yes])
202
203 dnl Arg, linux and bsd put their statfs function in different places
204 AH_TEMPLATE(HAVE_SYS_VFS_H, [Define to 1 if sys/vfs.h is available])
205 AH_TEMPLATE(HAVE_SYS_MOUNT_H, [Define to 1 if sys/mount.h is available])
206 if test "$have_statvfs" != "yes"; then
207    AC_EGREP_HEADER(statfs,sys/vfs.h,[AC_DEFINE(HAVE_SYS_VFS_H)],[
208         AC_EGREP_HEADER(statfs,sys/mount.h,[AC_DEFINE(HAVE_SYS_MOUNT_H)],
209                         [AC_MSG_ERROR(failed: Need statvfs)])
210    ])
211 fi
212
213 dnl We should use the real timegm function if we have it.
214 AH_TEMPLATE(HAVE_TIMEGM, [Define to 1 if timegm is available])
215 AC_CHECK_FUNC(timegm,AC_DEFINE(HAVE_TIMEGM))
216 AC_SUBST(HAVE_TIMEGM)
217
218 dnl HP-UX sux..
219 AH_TEMPLATE(NEED_SOCKLEN_T_DEFINE, [Define to 1 if socket_t is missing])
220 AC_MSG_CHECKING(for missing socklen_t)
221 AC_EGREP_HEADER(socklen_t, sys/socket.h,[AC_MSG_RESULT(no)],[
222         AC_DEFINE(NEED_SOCKLEN_T_DEFINE)
223         NEED_SOCKLEN_T_DEFINE=yes
224         AC_MSG_RESULT(missing.)])
225 AC_SUBST(NEED_SOCKLEN_T_DEFINE)
226
227 dnl HP-UX needs -d_XOPEN_SOURCE_EXTENDED for h_errno
228 AC_MSG_CHECKING(for h_errno)
229 AC_EGREP_HEADER(h_errno, netdb.h, [AC_MSG_RESULT(normal)],
230    [CPPFLAGS="$CPPFLAGS -D_XOPEN_SOURCE_EXTENDED"
231     AC_EGREP_HEADER(h_errno, netdb.h, 
232        [AC_MSG_RESULT(needs _XOPEN_SOURCE_EXTENDED)],
233        [AC_MSG_ERROR("not found.")])
234    ])
235
236 dnl Check for debiandoc
237 dnl AC_PATH_PROG(DEBIANDOC_HTML,debiandoc2html)
238 dnl AC_PATH_PROG(DEBIANDOC_TEXT,debiandoc2text)
239
240 AC_PATH_PROG([GPG],[gpg],[/usr/bin/gpg])
241
242 AM_GNU_GETTEXT_VERSION([0.14.5])
243 AM_GNU_GETTEXT([external])
244
245 dnl ah_NUM_PROCS
246 rc_GLIBC_VER
247 rc_LIBSTDCPP_VER
248 dnl ah_GCC3DEP
249
250 AC_CONFIG_FILES([
251           Makefile
252           lua/Makefile
253           apt-pkg/Makefile
254           methods/Makefile
255           cmdline/Makefile
256           tools/Makefile
257           doc/Makefile
258           test/Makefile
259           po/Makefile.in
260           ])
261 AC_CONFIG_LINKS([include/apti18n.h:buildlib/gettext.h])
262
263 AS_IF([test "$c9x_ints" = "no"],[
264 AC_CONFIG_LINKS([include/inttypes.h:buildlib/inttypes.h])
265 ])
266
267 AS_IF([test "$have_statvfs" != "yes"],[
268 AC_CONFIG_LINKS([include/statvfs.h:buildlib/statvfs.h])
269 ])
270
271 AS_IF([test "$NEED_SOCKLEN_T_DEFINE" = "yes"],[
272 AC_CONFIG_LINKS([include/netdb.h:buildlib/netdb.h])
273 ])
274
275 AC_OUTPUT