Merge branch 'master' of ssh://laiskiainen.org/home/pmatilai/apt-rpm/scm/apt
[apt.git] / configure.ac
1 dnl Process this file with autoconf to produce a configure script.
2
3 AC_PREREQ(2.59)
4 AC_INIT([apt],[0.5.15lorg3.93],[apt-rpm@lists.laiskiainen.org])
5 dnl Check the archs, we want the target type.
6 AC_CONFIG_AUX_DIR([buildlib])
7 AC_CANONICAL_HOST
8 AC_CONFIG_SRCDIR([AUTHORS.RPM])
9 AM_INIT_AUTOMAKE([foreign subdir-objects dist-bzip2 1.9.5])
10 AM_MAINTAINER_MODE
11
12 AC_CONFIG_HEADER([include/config.h:buildlib/config.h.in])
13 AC_CONFIG_HEADER([include/apt-pkg/aptconf.h:apt-pkg/aptconf.h.in])
14 AC_PROG_LIBTOOL
15
16 dnl Check our C compiler
17 AC_PROG_CC
18 AM_PROG_CC_C_O
19 AC_ISC_POSIX
20
21 dnl Check for other programs
22 AC_PROG_CXX
23 AC_PROG_CPP
24
25 dnl Checks for sockets
26 SAVE_LIBS="$LIBS"
27 LIBS=""
28 AC_SEARCH_LIBS(gethostbyname,nsl)
29 AC_SEARCH_LIBS(connect,socket)
30 SOCKETLIBS="$LIBS"
31 AC_SUBST(SOCKETLIBS)
32 LIBS="$SAVE_LIBS"
33  
34 dnl Checks for pthread -- disabled due to glibc bugs jgg
35 dnl AC_CHECK_LIB(pthread, pthread_create,[AC_DEFINE(HAVE_PTHREAD) PTHREADLIB="-lpthread"])
36 AC_SUBST(PTHREADLIB)
37 dnl if test "$PTHREADLIB" != "-lpthread"; then
38 dnl   AC_MSG_ERROR(failed: I need posix threads, pthread)
39 dnl fi
40
41 dnl Check for RPM executable path
42 AC_PATH_PROG(RPM_PATH,rpm,none)
43 if test "$RPM_PATH" = "none"; then
44    AC_MSG_ERROR([RPM executable was not found in your system])
45 else
46    AC_DEFINE_UNQUOTED([HAVE_RPM],1,[Define if RPM backend is available])
47
48    dnl Check for RPM version
49    AC_MSG_CHECKING(for RPM version)
50    RPM_VERSION_RAW=`LANG= LC_ALL= $RPM_PATH --version | sed 's/^RPM version //'`
51    RPM_VERSION_MAJOR=`echo $RPM_VERSION_RAW | cut -d. -f1`
52    RPM_VERSION_MINOR=`echo $RPM_VERSION_RAW | cut -d. -f2`
53    RPM_VERSION_MICRO=`echo $RPM_VERSION_RAW | cut -d. -f3`
54    if test -z "$RPM_VERSION_MAJOR" -o -z "$RPM_VERSION_MINOR"; then
55       AC_MSG_ERROR([can't parse RPM version])
56    fi
57    if test -z "$RPM_VERSION_MICRO"; then
58       RPM_VERSION_MICRO=0
59    fi
60    AC_DEFINE_UNQUOTED([RPM_VERSION_MAJOR],$RPM_VERSION_MAJOR,[RPM major version])
61    AC_DEFINE_UNQUOTED([RPM_VERSION_MINOR],$RPM_VERSION_MINOR,[RPM minor version])
62    AC_DEFINE_UNQUOTED([RPM_VERSION_MICRO],$RPM_VERSION_MICRO,[RPM micro version])
63    AC_DEFINE_UNQUOTED([RPM_VERSION],
64       [((RPM_VERSION_MAJOR<<16)|(RPM_VERSION_MINOR<<8)|RPM_VERSION_MICRO)],
65       [Define to the RPM version])
66    AC_DEFINE_UNQUOTED([RPM_VERSION_RAW],"$RPM_VERSION_RAW",[RPM raw version])
67    AC_MSG_RESULT($RPM_VERSION_RAW)
68
69    dnl Check for RPM libraries and headers
70
71    AC_CHECK_LIB(bz2,BZ2_bzopen, [],
72                 [AC_MSG_ERROR([Can't find libbz2 library])])
73    AC_CHECK_LIB(z,gzopen, [],
74                 [AC_MSG_ERROR([Can't find libz library])])
75    AC_CHECK_HEADERS(db1/db.h)
76
77    AC_CHECK_HEADER(rpm/rpmlib.h, [],
78                    [AC_MSG_ERROR([Can't find rpmlib.h])])
79    AC_CHECK_HEADERS([rpm/rpmsx.h rpm/misc.h])
80
81    if test $RPM_VERSION_MAJOR -lt 4; then
82       RPMLIBS="-lrpm -lz -lbz2 -lpopt"
83    else
84       AC_CHECK_LIB(rpmdb,rpmdbOpen,
85          [RPMDBLIBS="-lrpmdb"],
86          [RPMDBLIBS="-ldb-3.1"],
87          [-lrpm -lrpmio -lz -lbz2 -lpopt])
88       RPMLIBS="-lrpm $RPMDBLIBS -lrpmio -lz -lbz2 -lpopt"
89    fi
90    AC_MSG_CHECKING(for RPM libraries)
91    AC_MSG_RESULT($RPMLIBS)
92    AC_SUBST(RPMLIBS)
93 fi
94
95 dnl Can we use g++ hash_map?
96 AH_TEMPLATE(APT_WITH_GNU_HASH_MAP,
97             [Define to 1 if you want to use the g++ hash_map extension])
98 AC_MSG_CHECKING(for g++ hash_map extension)
99 AC_LANG_PUSH([C++])
100 AC_TRY_LINK(
101 [
102 #include <ext/hash_map>
103 using namespace __gnu_cxx;
104 ],[hash_map<char*,hash<char*> > HashMap;
105 ],[AC_DEFINE_UNQUOTED(APT_WITH_GNU_HASH_MAP, 1) AC_MSG_RESULT(yes)
106 ],[AC_MSG_RESULT(no)])
107 AC_LANG_POP([C++])
108
109 dnl sqlite3
110 SAVE_LIBS="$LIBS"
111 LIBS=""
112 AC_SEARCH_LIBS([sqlite3_open], [sqlite3], [], [have_sqlite3="no"])
113 if test "x$have_sqlite3" != "xno"; then
114    AC_DEFINE([WITH_SQLITE3], [1], [yes])
115    SQLITE3LIBS="$LIBS"
116 fi
117 LIBS="$SAVE_LIBS"
118
119 AM_CONDITIONAL([WITH_SQLITE3], [test ! "x$have_sqlite3" = "no"])
120 AC_SUBST(SQLITE3LIBS)
121
122 dnl CNC:2003-03-20
123 AC_MSG_CHECKING(for --disable-scripts)
124 AC_ARG_ENABLE([scripts],
125               AS_HELP_STRING([--disable-scripts],[disable the lua script extension system]),
126               [enable_scripts="$enableval"],[enable_scripts="yes"])
127 if test "$enable_scripts" != "no"; then
128   AC_MSG_RESULT(no)
129   AC_DEFINE(APT_WITH_LUA, 1, 
130             [Define if you want to enable the extension system]) 
131 else
132   AC_MSG_RESULT(yes)
133 fi
134 AM_CONDITIONAL(WITH_LUA, test "$enable_scripts" != "no")
135
136 dnl SELinux support
137 AC_MSG_CHECKING(for --disable-selinux)
138 AC_ARG_ENABLE([selinux],
139               AS_HELP_STRING([--disable-selinux],
140                              [disable SELinux support]),
141               [enable_selinux="$enableval"],[enable_selinux="yes"])
142 if test "$enable_selinux" != "no"; then
143   AC_MSG_RESULT(no)
144   AC_DEFINE(WITH_SELINUX, 1, 
145             [Define if you want to enable SELinux support]) 
146 else
147   AC_MSG_RESULT(yes)
148 fi
149 AM_CONDITIONAL(WITH_SELINUX, test "$enable_selinux" != "no")
150
151
152 dnl Repomd support
153 AC_MSG_CHECKING(for --disable-repomd)
154 AC_ARG_ENABLE([repomd],
155               AS_HELP_STRING([--disable-repomd],
156                              [disable repomd support]),
157               [enable_repomd="$enableval"],[enable_repomd="yes"])
158 if test "$enable_repomd" != "no"; then
159   AC_MSG_RESULT(no)
160   AC_DEFINE(APT_WITH_REPOMD, 1, [Define if you want to enable repomd support]) 
161   ## xmlReadFile is not available before 2.6.0
162   PKG_CHECK_MODULES([LIBXML2],[libxml-2.0 >= 2.6])
163   RPMLIBS="$LIBXML2_LIBS $RPMLIBS"
164   CPPFLAGS="$LIBXML2_CFLAGS $CPPFLAGS"
165   ## FIXME: Conditionalize this properly. We can support xml repomd without 
166   ## sqlite and repodb with libxml2 older than 2.6. In addition, rollback
167   ## will be using sqlite as well, we only want to check for it once.
168   RPMLIBS="$RPMLIBS $SQLITE3LIBS"
169 else
170   AC_MSG_RESULT(yes)
171 fi
172 AM_CONDITIONAL(WITH_REPOMD, test "$enable_repomd" != "no")
173
174 dnl Before configuring libtool check for --enable-static-progs option
175 AC_MSG_CHECKING(for --enable-static-progs)
176 AC_ARG_ENABLE(static-progs,
177               AS_HELP_STRING([--enable-static-progs],
178                              [build completely static (standalone) binaries]),
179               [enable_static_progs="$enableval"],[enable_static_progs="no"])
180 AM_CONDITIONAL(COMPILE_STATIC, test "$enable_static_progs" = "yes")
181 if test "$enable_static_progs" = "yes" ; then
182   AC_MSG_RESULT(yes)
183 else
184   AC_MSG_RESULT(no)
185 fi
186
187 dnl Check for apt-shell dependencies
188 AC_CHECK_LIB(ncurses,tputs,
189   [AC_CHECK_HEADER(readline/readline.h,
190      [AC_CHECK_LIB(readline,rl_completion_matches,
191         [compile_aptshell=yes],,[-lncurses])])])
192 AM_CONDITIONAL(COMPILE_APTSHELL, test "$compile_aptshell" = "yes")
193
194 dnl Converts the ARCH to be something singular for this general CPU family
195 dnl This is often the dpkg architecture string.
196 AH_TEMPLATE(COMMON_CPU, [Define the common CPU])
197 AH_TEMPLATE(COMMON_OS, [Define the common OS])
198 AC_MSG_CHECKING(system architecture)
199 archset="`awk \" ! /^#|^\\\$/ { if(match(\\\"$host_cpu\\\",\\\"^\\\"\\\$1\\\"\\\$\\\")) {print \\\$2; exit}}\" $srcdir/buildlib/archtable`"
200 if test "x$archset" = "x"; then
201   AC_MSG_ERROR(failed: use --host=)
202 fi
203 AC_MSG_RESULT($archset)
204 AC_DEFINE_UNQUOTED(COMMON_CPU,"$archset")
205
206 dnl Get a common name for the host OS - this is primarily only for HURD and is
207 dnl non fatal if it fails
208 AC_MSG_CHECKING(system OS)
209 osset="`awk \" ! /^#|^\\\$/ {if (match(\\\"$host_vendor-$host_os\\\",\\\$1)) {print \\\$2; exit}}\" $srcdir/buildlib/ostable`"
210 AC_MSG_RESULT($osset)
211 AC_DEFINE_UNQUOTED(COMMON_OS,"$osset")
212
213 dnl We use C99 types if at all possible
214 AC_CACHE_CHECK([for C99 integer types],c9x_ints,[
215     AC_TRY_COMPILE([#include <inttypes.h>],
216                    [uint8_t Foo1;uint16_t Foo2;uint32_t Foo3;],
217                    c9x_ints=yes,c9x_ints=no)])
218
219 AC_C_BIGENDIAN
220
221 dnl Check the sizes etc. of the architecture
222 dnl Cross compilers can either get a real C library or preload the cache
223 dnl with their size values.
224 AC_CHECK_SIZEOF(char)
225 AC_CHECK_SIZEOF(int)
226 AC_CHECK_SIZEOF(short)
227 AC_CHECK_SIZEOF(long)
228
229 dnl Single Unix Spec statvfs
230 AC_CHECK_FUNC(statvfs,[have_statvfs=yes])
231
232 dnl Arg, linux and bsd put their statfs function in different places
233 AH_TEMPLATE(HAVE_SYS_VFS_H, [Define to 1 if sys/vfs.h is available])
234 AH_TEMPLATE(HAVE_SYS_MOUNT_H, [Define to 1 if sys/mount.h is available])
235 if test "$have_statvfs" != "yes"; then
236    AC_EGREP_HEADER(statfs,sys/vfs.h,[AC_DEFINE(HAVE_SYS_VFS_H)],[
237         AC_EGREP_HEADER(statfs,sys/mount.h,[AC_DEFINE(HAVE_SYS_MOUNT_H)],
238                         [AC_MSG_ERROR(failed: Need statvfs)])
239    ])
240 fi
241
242 dnl We should use the real timegm function if we have it.
243 AH_TEMPLATE(HAVE_TIMEGM, [Define to 1 if timegm is available])
244 AC_CHECK_FUNC(timegm,AC_DEFINE(HAVE_TIMEGM))
245 AC_SUBST(HAVE_TIMEGM)
246
247 dnl HP-UX sux..
248 AH_TEMPLATE(NEED_SOCKLEN_T_DEFINE, [Define to 1 if socket_t is missing])
249 AC_MSG_CHECKING(for missing socklen_t)
250 AC_EGREP_HEADER(socklen_t, sys/socket.h,[AC_MSG_RESULT(no)],[
251         AC_DEFINE(NEED_SOCKLEN_T_DEFINE)
252         NEED_SOCKLEN_T_DEFINE=yes
253         AC_MSG_RESULT(missing.)])
254 AC_SUBST(NEED_SOCKLEN_T_DEFINE)
255
256 dnl HP-UX needs -d_XOPEN_SOURCE_EXTENDED for h_errno
257 AC_MSG_CHECKING(for h_errno)
258 AC_EGREP_HEADER(h_errno, netdb.h, [AC_MSG_RESULT(normal)],
259    [CPPFLAGS="$CPPFLAGS -D_XOPEN_SOURCE_EXTENDED"
260     AC_EGREP_HEADER(h_errno, netdb.h, 
261        [AC_MSG_RESULT(needs _XOPEN_SOURCE_EXTENDED)],
262        [AC_MSG_ERROR("not found.")])
263    ])
264
265 dnl Check for debiandoc
266 dnl AC_PATH_PROG(DEBIANDOC_HTML,debiandoc2html)
267 dnl AC_PATH_PROG(DEBIANDOC_TEXT,debiandoc2text)
268
269 AC_PATH_PROG([GPG],[gpg],[/usr/bin/gpg])
270
271 AM_GNU_GETTEXT_VERSION([0.14.5])
272 AM_GNU_GETTEXT([external])
273
274 dnl ah_NUM_PROCS
275 dnl rc_GLIBC_VER
276 dnl rc_LIBSTDCPP_VER
277 dnl ah_GCC3DEP
278
279 AC_CONFIG_FILES([
280           Makefile
281           lua/Makefile
282           apt-pkg/Makefile
283           apt-pkg/libapt-pkg.pc
284           methods/Makefile
285           cmdline/Makefile
286           tools/Makefile
287           doc/Makefile
288           test/Makefile
289           po/Makefile.in
290           ])
291 AC_CONFIG_LINKS([include/apti18n.h:buildlib/gettext.h])
292
293 AS_IF([test "$c9x_ints" = "no"],[
294 AC_CONFIG_LINKS([include/inttypes.h:buildlib/inttypes.h])
295 ])
296
297 AS_IF([test "$have_statvfs" != "yes"],[
298 AC_CONFIG_LINKS([include/statvfs.h:buildlib/statvfs.h])
299 ])
300
301 AS_IF([test "$NEED_SOCKLEN_T_DEFINE" = "yes"],[
302 AC_CONFIG_LINKS([include/netdb.h:buildlib/netdb.h])
303 ])
304
305 AC_OUTPUT