- bump version
[apt.git] / configure.in
1 dnl Process this file with autoconf to produce a configure script.
2
3 AC_PREREQ(2.54)
4 AC_INIT([apt],[0.5.15lorg2])
5 dnl Check the archs, we want the target type.
6 AC_CONFIG_AUX_DIR([buildlib])
7 AC_CANONICAL_HOST
8 AC_CONFIG_SRCDIR([configure.in])
9 AM_INIT_AUTOMAKE([foreign subdir-objects dist-bzip2 1.7])
10 AM_MAINTAINER_MODE
11
12 AC_CONFIG_HEADER([include/config.h:buildlib/config.h.in])
13
14 AC_PROG_LIBTOOL
15
16 dnl Check our C compiler
17 AC_PROG_CC
18 AM_PROG_CC_C_O
19 AC_ISC_POSIX
20
21 dnl Check for other programs
22 AC_PROG_CXX
23 AC_PROG_CPP
24
25 dnl Checks for sockets
26 SAVE_LIBS="$LIBS"
27 LIBS=""
28 AC_SEARCH_LIBS(gethostbyname,nsl)
29 AC_SEARCH_LIBS(connect,socket)
30 SOCKETLIBS="$LIBS"
31 AC_SUBST(SOCKETLIBS)
32 LIBS="$SAVE_LIBS"
33  
34 dnl Checks for pthread -- disabled due to glibc bugs jgg
35 dnl AC_CHECK_LIB(pthread, pthread_create,[AC_DEFINE(HAVE_PTHREAD) PTHREADLIB="-lpthread"])
36 AC_SUBST(PTHREADLIB)
37 dnl if test "$PTHREADLIB" != "-lpthread"; then
38 dnl   AC_MSG_ERROR(failed: I need posix threads, pthread)
39 dnl fi
40
41 dnl Check for RPM executable path
42 AC_PATH_PROG(RPM_PATH,rpm,none)
43 if test "$RPM_PATH" = "none"; then
44    AC_MSG_ERROR([RPM executable was not found in your system])
45 else
46    AC_DEFINE_UNQUOTED([HAVE_RPM],1,[Define if RPM backend is available])
47
48    dnl Check for RPM version
49    AC_MSG_CHECKING(for RPM version)
50    RPM_VERSION_RAW=`LANG= LC_ALL= $RPM_PATH --version | sed 's/^RPM version //'`
51    RPM_VERSION_MAJOR=`echo $RPM_VERSION_RAW | cut -d. -f1`
52    RPM_VERSION_MINOR=`echo $RPM_VERSION_RAW | cut -d. -f2`
53    RPM_VERSION_MICRO=`echo $RPM_VERSION_RAW | cut -d. -f3`
54    if test -z "$RPM_VERSION_MAJOR" -o -z "$RPM_VERSION_MINOR"; then
55       AC_MSG_ERROR([can't parse RPM version])
56    fi
57    if test -z "$RPM_VERSION_MICRO"; then
58       RPM_VERSION_MICRO=0
59    fi
60    AC_DEFINE_UNQUOTED([RPM_VERSION_MAJOR],$RPM_VERSION_MAJOR,[RPM major version])
61    AC_DEFINE_UNQUOTED([RPM_VERSION_MINOR],$RPM_VERSION_MINOR,[RPM minor version])
62    AC_DEFINE_UNQUOTED([RPM_VERSION_MICRO],$RPM_VERSION_MICRO,[RPM micro version])
63    AC_DEFINE_UNQUOTED([RPM_VERSION],
64       [((RPM_VERSION_MAJOR<<16)|(RPM_VERSION_MINOR<<8)|RPM_VERSION_MICRO)],
65       [Define to the RPM version])
66    AC_DEFINE_UNQUOTED([RPM_VERSION_RAW],"$RPM_VERSION_RAW",[RPM raw version])
67    AC_MSG_RESULT($RPM_VERSION_RAW)
68
69    dnl Check for RPM libraries and headers
70
71    AC_CHECK_LIB(bz2,BZ2_bzopen, [],
72                 [AC_MSG_ERROR([Can't find libbz2 library])])
73    AC_CHECK_LIB(z,gzopen, [],
74                 [AC_MSG_ERROR([Can't find libz library])])
75    AC_CHECK_HEADERS(db1/db.h)
76
77    CPPFLAGS="$CPPFLAGS -I/usr/include/rpm"
78    AC_CHECK_HEADER(rpm/rpmlib.h, [],
79                    [AC_MSG_ERROR([Can't find rpmlib.h])])
80
81    if test $RPM_VERSION_MAJOR -lt 4; then
82       RPMLIBS="-lrpm -lz -lbz2 -lpopt"
83    else
84       AC_CHECK_LIB(rpmdb,rpmdbOpen,
85          [RPMDBLIBS="-lrpmdb"],
86          [RPMDBLIBS="-ldb-3.1"],
87          [-lrpm -lrpmio -lz -lbz2 -lpopt])
88       RPMLIBS="-lrpm $RPMDBLIBS -lrpmio -lz -lbz2 -lpopt"
89    fi
90    AC_MSG_CHECKING(for RPM libraries)
91    AC_MSG_RESULT($RPMLIBS)
92    AC_SUBST(RPMLIBS)
93 fi
94
95 dnl Can we use g++ hash_map?
96 AH_TEMPLATE(WITH_GNU_HASH_MAP,
97             [Define to 1 if you want to use the g++ hash_map extension.])
98 AC_MSG_CHECKING(for g++ hash_map extension)
99 AC_LANG_PUSH([C++])
100 AC_TRY_LINK(
101 [
102 #include <ext/hash_map>
103 using namespace __gnu_cxx;
104 ],[hash_map<char*,hash<char*> > HashMap;
105 ],[AC_DEFINE_UNQUOTED(WITH_GNU_HASH_MAP, 1) AC_MSG_RESULT(yes)
106 ],[AC_MSG_RESULT(no)])
107 AC_LANG_POP([C++])
108
109 dnl CNC:2003-03-20
110 AC_MSG_CHECKING(for --disable-scripts)
111 AC_ARG_ENABLE([scripts],
112               AC_HELP_STRING(--disable-scripts, disable the extension system),
113               [enable_scripts="$enableval"],[enable_scripts="yes"])
114 if test "$enable_scripts" != "no"; then
115   AC_MSG_RESULT(no)
116   AC_DEFINE(WITH_LUA, 1, 
117             [Define if you want to enable the extension system.]) 
118 else
119   AC_MSG_RESULT(yes)
120 fi
121 AM_CONDITIONAL(WITH_LUA, test "$enable_scripts" != "no")
122
123 dnl Before configuring libtool check for --enable-static-progs option
124 AC_MSG_CHECKING(for --enable-static-progs)
125 AC_ARG_ENABLE(static-progs,
126               AC_HELP_STRING([--enable-static-progs],
127                              [Build completely static (standalone) binaries.]),
128               [enable_static_progs="$enableval"],[enable_static_progs="no"])
129 AM_CONDITIONAL(COMPILE_STATIC, test "$enable_static_progs" = "yes")
130 if test "$enable_static_progs" = "yes" ; then
131   AC_MSG_RESULT(yes)
132 else
133   AC_MSG_RESULT(no)
134 fi
135
136 dnl Check for apt-shell dependencies
137 AC_CHECK_LIB(ncurses,tputs,
138   [AC_CHECK_HEADER(readline/readline.h,
139      [AC_CHECK_LIB(readline,rl_completion_matches,
140         [compile_aptshell=yes],,[-lncurses])])])
141 AM_CONDITIONAL(COMPILE_APTSHELL, test "$compile_aptshell" = "yes")
142
143 dnl Converts the ARCH to be something singular for this general CPU family
144 dnl This is often the dpkg architecture string.
145 AH_TEMPLATE(COMMON_CPU, [Define the common CPU])
146 AH_TEMPLATE(COMMON_OS, [Define the common OS])
147 AC_MSG_CHECKING(system architecture)
148 archset="`awk \" ! /^#|^\\\$/ { if(match(\\\"$host_cpu\\\",\\\"^\\\"\\\$1\\\"\\\$\\\")) {print \\\$2; exit}}\" $srcdir/buildlib/archtable`"
149 if test "x$archset" = "x"; then
150   AC_MSG_ERROR(failed: use --host=)
151 fi
152 AC_MSG_RESULT($archset)
153 AC_DEFINE_UNQUOTED(COMMON_CPU,"$archset")
154
155 dnl Get a common name for the host OS - this is primarily only for HURD and is
156 dnl non fatal if it fails
157 AC_MSG_CHECKING(system OS)
158 osset="`awk \" ! /^#|^\\\$/ {if (match(\\\"$host_vendor-$host_os\\\",\\\$1)) {print \\\$2; exit}}\" $srcdir/buildlib/ostable`"
159 AC_MSG_RESULT($osset)
160 AC_DEFINE_UNQUOTED(COMMON_OS,"$osset")
161
162 dnl We use C99 types if at all possible
163 AC_CACHE_CHECK([for C99 integer types],c9x_ints,[
164     AC_TRY_COMPILE([#include <inttypes.h>],
165                    [uint8_t Foo1;uint16_t Foo2;uint32_t Foo3;],
166                    c9x_ints=yes,c9x_ints=no)])
167 AM_CONDITIONAL(NEED_INTTYPES_H, test "$c9x_ints" = "no")
168
169 AC_C_BIGENDIAN
170
171 dnl Check the sizes etc. of the architecture
172 dnl Cross compilers can either get a real C library or preload the cache
173 dnl with their size values.
174 AC_CHECK_SIZEOF(char)
175 AC_CHECK_SIZEOF(int)
176 AC_CHECK_SIZEOF(short)
177 AC_CHECK_SIZEOF(long)
178
179 dnl Single Unix Spec statvfs
180 AC_CHECK_FUNC(statvfs,[have_statvfs=yes])
181 AM_CONDITIONAL(NEED_STATVFS_H, test "$have_statvfs" != "yes")
182
183 dnl Arg, linux and bsd put their statfs function in different places
184 AH_TEMPLATE(HAVE_VFS_H, [Define to 1 if sys/vfs.h is available])
185 AH_TEMPLATE(HAVE_MOUNT_H, [Define to 1 if sys/mount.h is available])
186 if test "$have_statvfs" != "yes"; then
187    AC_EGREP_HEADER(statfs,sys/vfs.h,[AC_DEFINE(HAVE_VFS_H)],[
188         AC_EGREP_HEADER(statfs,sys/mount.h,[AC_DEFINE(HAVE_MOUNT_H)],
189                         [AC_MSG_ERROR(failed: Need statvfs)])
190    ])
191 fi
192
193 dnl We should use the real timegm function if we have it.
194 AH_TEMPLATE(HAVE_TIMEGM, [Define to 1 if timegm is available])
195 AC_CHECK_FUNC(timegm,AC_DEFINE(HAVE_TIMEGM))
196 AC_SUBST(HAVE_TIMEGM)
197
198 dnl HP-UX sux..
199 AH_TEMPLATE(NEED_SOCKLEN_T_DEFINE, [Define to 1 if socket_t is missing])
200 AC_MSG_CHECKING(for missing socklen_t)
201 AC_EGREP_HEADER(socklen_t, sys/socket.h,[AC_MSG_RESULT(no)],[
202         AC_DEFINE(NEED_SOCKLEN_T_DEFINE)
203         NEED_SOCKLEN_T_DEFINE=yes
204         AC_MSG_RESULT(missing.)])
205 AC_SUBST(NEED_SOCKLEN_T_DEFINE)
206 AM_CONDITIONAL(NEED_NETDB_H, test "$NEED_SOCKLEN_T_DEFINE" = "yes")
207
208 dnl HP-UX needs -d_XOPEN_SOURCE_EXTENDED for h_errno
209 AC_MSG_CHECKING(for h_errno)
210 AC_EGREP_HEADER(h_errno, netdb.h, [AC_MSG_RESULT(normal)],
211    [CPPFLAGS="$CPPFLAGS -D_XOPEN_SOURCE_EXTENDED"
212     AC_EGREP_HEADER(h_errno, netdb.h, 
213        [AC_MSG_RESULT(needs _XOPEN_SOURCE_EXTENDED)],
214        [AC_MSG_ERROR("not found.")])
215    ])
216
217 dnl Check for debiandoc
218 dnl AC_PATH_PROG(DEBIANDOC_HTML,debiandoc2html)
219 dnl AC_PATH_PROG(DEBIANDOC_TEXT,debiandoc2text)
220
221 dnl Check for the SGML tools needed to build man pages
222 AC_PATH_PROG(DOCBOOK2MAN,docbook2man)
223 AC_MSG_CHECKING([for --disable-docs])
224 AC_ARG_ENABLE([docs],
225               AC_HELP_STRING([--disable-docs],
226                              [do not compile documentation]),
227               [enable_docs="$enableval"], [enable_docs="yes"])
228 if test "$enable_docs" != "no"; then
229         AC_MSG_RESULT(no)
230 else
231         AC_MSG_RESULT(yes)
232 fi
233 AM_CONDITIONAL(COMPILE_MANPAGES, test -n "$DOCBOOK2MAN" -a "$enable_docs" != "no")
234
235 AM_GNU_GETTEXT_VERSION([0.11.4])
236 AM_GNU_GETTEXT
237
238 dnl ah_NUM_PROCS
239 rc_GLIBC_VER
240 rc_LIBSTDCPP_VER
241 dnl ah_GCC3DEP
242
243 dnl Fix up intl/Makefile to point to the right config.h
244 AC_CONFIG_COMMANDS([fixintl],[
245         sed -e 's,\.\./config.h,$(top_builddir)/include/config.h,g' \
246             -e 's,^\(INCLUDES = .*\)$,\1 -I$(top_builddir)/include,g' \
247             intl/Makefile > intl/Makefile.tmp
248         mv -f intl/Makefile{.tmp,}
249 ])
250
251 AC_OUTPUT([
252           Makefile
253           buildlib/Makefile
254           intl/Makefile 
255           lua/Makefile
256           apt-pkg/Makefile
257           methods/Makefile
258           cmdline/Makefile
259           tools/Makefile
260           doc/Makefile
261           m4/Makefile 
262           po/Makefile.in
263           ])